Try also /home/<user>/.logo.pgn for user logo
[xboard.git] / configure.ac
1 dnl| configure.in
2 dnl|
3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
4 dnl| 2008, 2009, 2010, 2011, 2012, 2013, 2014 Free Software Foundation, Inc.
5 dnl|
6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
7 dnl| it under the terms of the GNU General Public License as published by
8 dnl| the Free Software Foundation, either version 3 of the License, or (at
9 dnl| your option) any later version.
10 dnl|
11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
14 dnl| General Public License for more details.
15 dnl|
16 dnl| You should have received a copy of the GNU General Public License
17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
18 dnl|
19 dnl| --------------------------------------------------------------------
20 dnl|
21 dnl| You can process this file with autoconf to produce a configure script.
22 dnl| However, normally the supplied configure script will work fine.
23 dnl|
24 dnl| If you do need to change the configure script, instead of editing
25 dnl| it directly, try to edit configure.in (in a way that will keep
26 dnl| it portable to sites and systems other than your own), and run autoconf
27 dnl| to regenerate configure.  Then submit your changes to be folded into
28 dnl| the standard version of xboard.
29
30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
31 AC_INIT([xboard],[master-20140119],[bug-xboard@gnu.org])
32
33 dnl| need this to be able to compile some files in a subdir (filebrowser)
34 AM_INIT_AUTOMAKE([subdir-objects])
35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
36
37 AC_CONFIG_HEADERS([config.h])
38
39 dnl | a bunch of templates for defines used below
40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
44 AH_TEMPLATE([HAVE_RANDOM],[template])
45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
46 AH_TEMPLATE([IBMRTAIX],[template])
47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
48 AH_TEMPLATE([PTY_ITERATION],[template])
49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
50 AH_TEMPLATE([PTY_OPEN],[template])
51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
52 AH_TEMPLATE([REMOTE_SHELL],[template])
53 AH_TEMPLATE([RTU],[template])
54 AH_TEMPLATE([UNIPLUS],[template])
55 AH_TEMPLATE([USE_PTYS],[template])
56 AH_TEMPLATE([X_WCHAR],[template])
57 AH_TEMPLATE([ATTENTION],[template])
58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
59 AH_TEMPLATE([USE_XAW3D],[template])
60 AH_TEMPLATE([X_LOCALE],[template])
61
62
63
64 if test -z "$CFLAGS" ; then
65 dnl| Prevent the next macro from setting CFLAGS to -g
66   CFLAGS=" "
67 fi
68 AC_PROG_CC
69
70 dnl| need this to be able to compile files in a subdir
71 AM_PROG_CC_C_O
72
73 AC_PROG_CPP
74 AC_ISC_POSIX
75 AC_PROG_INSTALL
76
77 dnl| add gettext support
78 AM_GNU_GETTEXT_VERSION(0.17)
79 AM_GNU_GETTEXT([external])
80
81 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
82 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
83 if test "$MINFO" = makeinfo_not_found ; then
84    echo Please install \"makeinfo\"
85    exit 1
86 fi
87 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
88 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
89 AC_SUBST(NROFFFLAGS)
90 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
91 AC_PATH_PROGS(PERLPATH, perl)
92
93 AC_HEADER_STDC
94 AC_HEADER_TIME
95 AC_HEADER_SYS_WAIT
96 AC_HEADER_DIRENT
97 AC_TYPE_SIGNAL
98 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
99 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
100 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
101 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
102
103 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
104 AC_CHECK_FUNCS(gettimeofday ftime, break)
105 AC_CHECK_FUNCS(random rand48, break)
106 AC_CHECK_FUNCS(gethostname sysinfo, break)
107 AC_CHECK_FUNC(setlocale, [],
108   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
109
110 AC_CHECK_LIB(seq, getpseudotty)
111
112 dnl | add compiler warnings only if compiler understands them
113 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
114 SAVE_CFLAGS="$CFLAGS"
115 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
116 AC_TRY_COMPILE([],[],
117   AC_MSG_RESULT(yes),
118   AC_MSG_RESULT(no)
119   CFLAGS="$SAVE_CFLAGS")
120
121 dnl | check for pkg-config
122 AC_CHECK_PROGS([PKGCONFIG], [pkg-config], pkgconfig_not_found)
123 AS_IF( [test "x$PKGCONFIG" = xpkgconfig_not_found],
124        AC_MSG_ERROR([cannot find pkg-config! Please install it.]))
125
126 dnl | check for cairo and librsvg
127 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
128 AC_SUBST(CAIRO_CFLAGS)
129 AC_SUBST(CAIRO_LIBS)
130
131 dnl | check which front end to use
132 dnl | first check for gtk
133 dnl | then for Xaw3d
134 dnl | and then for Xaw
135 FRONTEND_CFLAGS=""
136 FRONTEND_LIBS=""
137
138 AC_ARG_WITH([gtk],
139             [AS_HELP_STRING([--with-gtk],[use GTK front-end (experimental)])],
140             [with_GTK=$withval],
141             [with_GTK="no"])
142
143 AC_ARG_WITH([Xaw3d],
144             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
145             [with_Xaw3d="$withval"],
146             [with_Xaw3d="no"])
147
148 AC_ARG_WITH([Xaw],
149             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end (default)])],
150             [with_Xaw="$withval"],
151             [with_Xaw="yes"])
152
153 AC_ARG_WITH([iconsdir],
154             [AS_HELP_STRING([--with-iconsdir=DIR],
155             [path where icons get installed (default: $datadir/icons/hicolor/48x48/apps)])],
156             [ICONSDIR="$withval"],
157             [ICONSDIR='$(datadir)/icons/hicolor/48x48/apps'])
158
159 AC_ARG_WITH([svgiconsdir],
160             [AS_HELP_STRING([--with-svgiconsdir=DIR],
161             [path where svg icons get installed (default: $datadir/icons/hicolor/scalable/apps)])],
162             [SVGICONSDIR="$withval"],
163             [SVGICONSDIR='$(datadir)/icons/hicolor/scalable/apps'])
164
165 AC_ARG_WITH([desktopdir],
166             [AS_HELP_STRING([--with-desktopdir=DIR],
167                             [path where desktop files get installed (default: $datadir/applications)])],
168             [DESKTOPDIR="$withval"],
169             [DESKTOPDIR='$(datadir)/applications'])
170
171 AC_ARG_WITH([mimedir],
172             [AS_HELP_STRING([--with-mimedir=DIR],
173                             [path where mime files get installed (default: $datadir/mime/packages)])],
174             [MIMEDIR="$withval"],
175             [MIMEDIR='$(datadir)/mime/packages'])
176
177 AC_ARG_WITH([gamedatadir],
178             [AS_HELP_STRING([--with-gamedatadir=DIR],
179                             [path where game data files get installed (default: $datadir/games/xboard)])],
180             [GAMEDATADIR="$withval"],
181             [GAMEDATADIR='$(datadir)/games/xboard'])
182
183 AC_SUBST(ICONSDIR)
184 AC_SUBST(SVGICONSDIR)
185 AC_SUBST(DESKTOPDIR)
186 AC_SUBST(MIMEDIR)
187 AC_SUBST(GAMEDATADIR)
188
189 dnl | check for libraries
190 if test x"$with_GTK" = x"yes" ; then
191   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
192   FRONTEND_CFLAGS=$GTK_CFLAGS
193   FRONTEND_LIBS=$GTK_LIBS
194   with_Xaw="no"
195 fi
196
197 if test x"$with_GTK" = x"no" ; then
198
199 dnl | general check for Xaw and Xaw3d
200   AC_PATH_XTRA
201   if test -n "$no_x" ; then
202     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
203     They were not found on your system.  See FAQ topic C.2.
204     configure failed"])
205   fi
206
207   save_cflags="$CFLAGS"
208   save_cppflags="$CPPFLAGS"
209   CFLAGS="$CFLAGS $X_CFLAGS"
210   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
211   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
212   CFLAGS="$save_cflags"
213   CPPFLAGS="$save_cppflags"
214
215   if test "$xt" = "no" ; then
216      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
217   fi
218
219 dnl | check availability of Xaw3d
220   FRONTEND_LIBS=
221   AS_IF([test x"$with_Xaw3d" != x"no"],
222             [AC_CHECK_LIB([Xaw3d],
223                     [XawTextReplace],
224                     [ FRONTEND_LIBS="-lXaw3d"
225                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
226                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
227                                [-lXaw])])
228
229 dnl | no Xaw3d, check for Xaw; make it the default
230   if test x"$with_Xaw3d" = x"no" ; then
231      with_Xaw=yes
232      save_cflags="$CFLAGS"
233      save_cppflags="$CPPFLAGS"
234      CFLAGS="$CFLAGS $X_CFLAGS"
235      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
236      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
237      CFLAGS="$save_cflags"
238      CPPFLAGS="$save_cppflags"
239
240      if test x"$xaw_headers" = x"no" ; then
241         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
242      fi
243
244      FRONTEND_LIBS="-lXaw"
245   fi
246
247 fi
248
249 dnl | make results available in Makefile.am
250 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
251 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes" || test x"$with_Xaw" = x"yes"])
252
253 dnl | end Front-end check
254
255 AC_CANONICAL_HOST
256
257 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
258 dnl| we are trying to find out whether this is a System-V derivative in
259 dnl| which pipes don't work with select() and if so, whether there is anything
260 dnl| strange about the way to open a pty.  Some of the work was done above
261 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
262 dnl| properties of particular systems are also handled here.
263
264 dnl| 4/6/97 I'm not sure there really are any systems where pipes
265 dnl| don't work with select(), and ptys cause problems on many
266 dnl| systems, so I'm changing the default to disable ptys in all
267 dnl| cases.  I will change it back if I get bug reports that are fixed
268 dnl| by doing a "configure --enable-ptys"
269
270 USE_PTYS=0
271 case "$host" in
272   *-*-hpux* )
273     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
274         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
275     AC_DEFINE(PTY_NAME_SPRINTF,
276         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
277 dnl| USE_PTYS=1
278     if test "$GCC" = yes; then
279       CONF_CFLAGS="-fwritable-strings"
280     else
281
282 dnl| Note: You might be able to build xboard even if your compiler does not
283 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
284 dnl| know whether the X header files on HP-UX require it.
285
286       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
287     fi
288
289 dnl| HP doesn't supply a full set of X header files and libraries.  People
290 dnl| often have some things installed in one place and some in another.
291 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
292 dnl| likely ones that might be missing here.  It might be better to
293 dnl| change AC_PATH_XTRA to try to extract this information from imake,
294 dnl| since folks who install the missing bits often configure their
295 dnl| imake to find them, but I don't want to delve into autoconf and
296 dnl| hack on its internals.
297
298     if test -d /opt/hppd/include/X11; then
299       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
300       X_LIBS="$X_LIBS -L/opt/hppd/lib"
301     elif test -d /usr/contrib/X11R5/include; then
302       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
303       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
304     elif test -d /usr/contrib/mitX11R5/include; then
305       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
306       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
307     elif test -d /MIT/X11R5/include; then
308       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
309       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
310     elif test -d /usr/local/include/X11R5; then
311       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
312       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
313     fi
314     if test -d /usr/include/X11R5; then
315       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
316       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
317     elif test -d /usr/include/X11R4; then
318       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
319       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
320     fi
321   ;;
322
323   romp-ibm-aix* )
324     AC_DEFINE(IBMRTAIX, 1)
325 dnl| USE_PTYS=1
326   ;;
327
328   i386-ibm-aix )
329 dnl| USE_PTYS=1
330     if test "$GCC" = yes; then
331       CONF_CFLAGS="-fwritable-strings"
332     fi
333   ;;
334
335   *-*-aix3* | *-*-bosx* )
336     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
337     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
338     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
339 dnl| USE_PTYS=1
340   ;;
341
342   *-*-cxux* )
343     AC_DEFINE(FIRST_PTY_LETTER, 'A')
344     AC_DEFINE(LAST_PTY_LETTER, 'P')
345 dnl| USE_PTYS=1
346   ;;
347
348   *-*-uniplus* )
349     AC_DEFINE(UNIPLUS, 1)
350 dnl| USE_PTYS=1
351   ;;
352
353   *-*-rtu* )
354     AC_DEFINE(FIRST_PTY_LETTER, 'z')
355     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
356         [sprintf (pty_name, "/dev/ttyp%x", i);])
357     AC_DEFINE(PTY_NAME_SPRINTF,
358         [sprintf (pty_name, "/dev/pty%x", i);])
359     AC_DEFINE(RTU, 1)
360 dnl| USE_PTYS=1
361   ;;
362
363   *-*-iris* | *-*-irix3* )
364     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
365     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
366     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
367         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
368 dnl| USE_PTYS=1
369   ;;
370
371   *-*-irix* )
372 dnl| USE_PTYS=1
373   ;;
374
375   *-*-sunos4* | *-*-solaris1* )
376
377 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
378 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
379 dnl|  "overkill," but doesn't explain what should be done instead.
380
381     if test "$GCC" = yes; then
382       PRE_XMULIB="-static"
383       POST_XMULIB="-dynamic"
384     else
385       PRE_XMULIB="-Bstatic"
386       POST_XMULIB="-Bdynamic"
387     fi
388   ;;
389
390   *-*-sunos5* | *-*-solaris2* )
391 dnl| USE_PTYS=1
392
393 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
394 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
395 dnl| code above.
396
397     X_LIBS="$X_LIBS -lelf"
398   ;;
399
400   *-*-sco* )
401     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
402     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
403     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
404 dnl| USE_PTYS=1
405   ;;
406
407   *-*-dynix* | *-*-ptx* )
408 dnl| USE_PTYS=1
409   ;;
410
411   *-*-esix* )
412 dnl| USE_PTYS=1
413   ;;
414
415   *-*-usg5-4* | *-*-sysvr4* )
416 dnl| USE_PTYS=1
417   ;;
418
419   *-*-usg* | *-*-sysv* | *-*-aix* )
420 dnl| USE_PTYS=1
421   ;;
422
423   vax-*-ultrix )
424     if test "$GCC" = yes; then
425       CONF_CFLAGS="-fwritable-strings"
426     fi
427   ;;
428
429 dnl| add some libs for OS X
430   *-apple-* )
431     AC_MSG_WARN([Apple support is experimental, please report any problems to bug-xboard@gnu.org])
432     AC_PATH_PROG(SW_VERS, sw_vers)
433     if test "x$SW_VERS" != "x"; then
434       AC_MSG_CHECKING(Mac OS X version)
435       MACOSX_VERSION=`$SW_VERS -productVersion`
436       AC_MSG_RESULT([$MACOSX_VERSION])
437     fi
438     case "$MACOSX_VERSION" in
439       10.0*|10.1|10.1.*|10.2*|10.3*|10.4*|10.5*|10.6*)
440       FRONTEND_LIBS="$FRONTEND_LIBS -lgtkmacintegration -headerpad_max_install_names mmacosx-version-min=10.6 -isysroot /Developer/SDKs/MacOSX10.6.sdk"
441         ;;
442       *)
443       FRONTEND_LIBS="$FRONTEND_LIBS -lgtkmacintegration -headerpad_max_install_names"
444         ;;
445     esac
446
447   ;;
448 esac
449
450
451 AC_SUBST(FRONTEND_CFLAGS)
452 AC_SUBST(FRONTEND_LIBS)
453 AC_SUBST(PRE_XMULIB)
454 AC_SUBST(POST_XMULIB)
455 AC_SUBST(CONF_CFLAGS)
456 AC_SUBST(CONF_LDFLAGS)
457
458 AC_MSG_CHECKING(whether ptys or pipes should be used)
459 AC_ARG_ENABLE( [ptys],
460                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
461 [if test "$enableval" = yes; then
462   USE_PTYS=1
463   enable_ptys="ptys"
464   AC_MSG_RESULT([ptys (user override)])
465 fi
466 if test "$enableval" = no; then
467   USE_PTYS=0
468   enable_ptys="pipes"
469   AC_MSG_RESULT([pipes (user override)])
470 fi],
471 [if test "$USE_PTYS" = 1; then
472   AC_MSG_RESULT(ptys)
473   enable_ptys="ptys"
474 else
475   AC_MSG_RESULT(pipes)
476   enable_ptys="pipes"
477 fi])
478 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
479
480
481 dnl | define not to build zippy as a default, so that autoheader is happy
482 AC_ARG_ENABLE( [zippy],
483                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
484                [],
485                [enable_zippy="no"])
486
487 if test x"$enable_zippy" != xno; then
488   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
489 else
490   AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
491 fi
492 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
493
494
495 AC_ARG_ENABLE(sigint,
496 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
497 [if test "$enableval" = yes; then
498   AC_DEFINE(ATTENTION, 1)
499 fi
500 enable_sigint=$enableval
501 ],
502 [enable_sigint="yes"
503 AC_DEFINE(ATTENTION, 1)])
504
505
506 if test x"$with_Xaw3d" = x"yes" -o  x"$with_Xaw" = x"yes" ; then
507 dnl | save all information for X in X_LIBS, also add the libraries themself
508 dnl | since AC_PATH_XTRA only adds the paths
509 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
510 AC_SUBST(X_CFLAGS)
511 AC_SUBST(X_LIBS)
512 fi
513
514 dnl | should we install desktop icons and mime associations?
515 AC_ARG_ENABLE(  [update-mimedb],
516                 [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
517                 [enable_mimedb="no"],
518                 [enable_mimedb="yes"])
519
520 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = "xyes")
521
522 if test x"$enable_mimedb" = "xyes"; then
523    AC_PATH_PROG([XDG_MIME],[xdg-mime])
524    AC_SUBST(XDG_MIME)
525    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
526    AC_SUBST(XDG_DESKTOP_MENU)
527    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
528    AC_SUBST(XDG_ICON_RESOURCE)
529 fi
530
531 dnl create a string with configure options that can be passed to the
532 dnl program, good for bug reports and version printout, see output below
533 CONFIGURE_OPTIONS="prefix=$prefix; datarootdir=$datarootdir; \
534 datadir=$datadir; gamedatadir=$GAMEDATADIR; desktopdir=$DESKTOPDIR; \
535 mimedir=$MIMEDIR; iconsdir=$ICONSDIR; svgiconsdir=$SVGICONSDIR; infodir=$infodir; \
536 sysconfigdir=$sysconfigdir; update_mimedb=$enable_mimedb; NLS=$USE_NLS; \
537 GKT=$with_GTK; Xaw3d=$with_Xaw3d; Xaw=$with_Xaw; \
538 ptys=$enable_ptys; zippy=$enable_zippy; sigint=$enable_sigint"
539
540 AC_SUBST(CONFIGURE_OPTIONS)
541
542 dnl |  output Makefile
543 AC_CONFIG_FILES([Makefile cmail po/Makefile.in])
544 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
545 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
546 AC_OUTPUT
547
548 dnl
549 dnl Output a summary
550 dnl
551 echo ""
552 echo " Configurations summary:"
553 echo ""
554 echo "        prefix:          $prefix       "
555 echo "        datarootdir:     $datarootdir  "
556 echo "        datadir:         $datadir      "
557 echo "        gamedatadir:     $GAMEDATADIR  "
558 echo "        desktopdir:      $DESKTOPDIR   "
559 echo "        mimedir:         $MIMEDIR      "
560 echo "        iconsdir:        $ICONSDIR     "
561 echo "        svgiconsdir:     $SVGICONSDIR  "
562 echo "        infodir:         $infodir   (info files will go here)"
563 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
564 echo ""
565 echo "        update mimedb:   $enable_mimedb"
566 echo ""
567 echo "        NLS support:     $USE_NLS"
568 echo ""
569 echo "        GTK:             $with_GTK"
570 echo "        Xaw3d:           $with_Xaw3d"
571 echo "        Xaw:             $with_Xaw"
572 echo ""
573 echo "        ptys:            $enable_ptys"
574 echo "        zippy:           $enable_zippy"
575 echo "        sigint:          $enable_sigint"