Merge remote-tracking branch 'origin/master' into v4.7.x
[xboard.git] / configure.ac
1 dnl| configure.in
2 dnl|
3 dnl| Copyright 1992-2001, 2002, 2003, 2004, 2005, 2006, 2007,
4 dnl| 2008, 2009, 2010, 2011, 2012, 2013 Free Software Foundation, Inc.
5 dnl|
6 dnl| GNU XBoard is free software: you can redistribute it and/or modify
7 dnl| it under the terms of the GNU General Public License as published by
8 dnl| the Free Software Foundation, either version 3 of the License, or (at
9 dnl| your option) any later version.
10 dnl|
11 dnl| GNU XBoard is distributed in the hope that it will be useful, but
12 dnl| WITHOUT ANY WARRANTY; without even the implied warranty of
13 dnl| MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
14 dnl| General Public License for more details.
15 dnl|
16 dnl| You should have received a copy of the GNU General Public License
17 dnl| along with this program. If not, see http://www.gnu.org/licenses/.
18 dnl|
19 dnl| --------------------------------------------------------------------
20 dnl|
21 dnl| You can process this file with autoconf to produce a configure script.
22 dnl| However, normally the supplied configure script will work fine.
23 dnl|
24 dnl| If you do need to change the configure script, instead of editing
25 dnl| it directly, try to edit configure.in (in a way that will keep
26 dnl| it portable to sites and systems other than your own), and run autoconf
27 dnl| to regenerate configure.  Then submit your changes to be folded into
28 dnl| the standard version of xboard.
29
30 dnl| define second argument as VERSION.PATCHLEVEL. e.g. 4.4.0j
31 AC_INIT([xboard],[4.7.0],[bug-xboard@gnu.org])
32
33 dnl| need this to be able to compile some files in a subdir (filebrowser)
34 AM_INIT_AUTOMAKE([subdir-objects])
35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
36
37 AC_CONFIG_HEADERS([config.h])
38
39 dnl | a bunch of templates for defines used below
40 AH_TEMPLATE([FIRST_PTY_LETTER],[template])
41 AH_TEMPLATE([HAVE_FCNTL_H],[template])
42 AH_TEMPLATE([HAVE_GETHOSTNAME],[template])
43 AH_TEMPLATE([HAVE_GETTIMEOFDAY],[template])
44 AH_TEMPLATE([HAVE_RANDOM],[template])
45 AH_TEMPLATE([HAVE_SYS_SOCKET_H],[template])
46 AH_TEMPLATE([IBMRTAIX],[template])
47 AH_TEMPLATE([LAST_PTY_LETTER],[template])
48 AH_TEMPLATE([PTY_ITERATION],[template])
49 AH_TEMPLATE([PTY_NAME_SPRINTF],[template])
50 AH_TEMPLATE([PTY_OPEN],[template])
51 AH_TEMPLATE([PTY_TTY_NAME_SPRINTF],[template])
52 AH_TEMPLATE([REMOTE_SHELL],[template])
53 AH_TEMPLATE([RTU],[template])
54 AH_TEMPLATE([UNIPLUS],[template])
55 AH_TEMPLATE([USE_PTYS],[template])
56 AH_TEMPLATE([X_WCHAR],[template])
57 AH_TEMPLATE([ATTENTION],[template])
58 AH_TEMPLATE([DEFINED_SYS_ERRLIST],[template])
59 AH_TEMPLATE([HAVE_LIBXPM],[template])
60 AH_TEMPLATE([USE_XAW3D],[template])
61 AH_TEMPLATE([X_LOCALE],[template])
62
63
64
65 if test -z "$CFLAGS" ; then
66 dnl| Prevent the next macro from setting CFLAGS to -g
67   CFLAGS=" "
68 fi
69 AC_PROG_CC
70
71 dnl| need this to be able to compile files in a subdir
72 AM_PROG_CC_C_O
73
74 AC_PROG_CPP
75 AC_ISC_POSIX
76 AC_PROG_INSTALL
77
78 dnl| add gettext support
79 AM_GNU_GETTEXT_VERSION(0.17)
80 AM_GNU_GETTEXT([external])
81
82 AC_CHECK_PROGS(RSH, remsh rsh, rsh)
83 AC_CHECK_PROGS(MINFO, makeinfo, makeinfo_not_found)
84 if test "$MINFO" = makeinfo_not_found ; then
85    echo Please install \"makeinfo\"
86    exit 1
87 fi
88 AC_DEFINE_UNQUOTED(REMOTE_SHELL, "$RSH")
89 AC_CHECK_PROG(NROFF, nroff, [nroff -man], cat)
90 AC_SUBST(NROFFFLAGS)
91 AC_PATH_PROGS(AWKPATH, awk mawk gawk nawk)
92 AC_PATH_PROGS(PERLPATH, perl)
93
94 AC_HEADER_STDC
95 AC_HEADER_TIME
96 AC_HEADER_SYS_WAIT
97 AC_HEADER_DIRENT
98 AC_TYPE_SIGNAL
99 AC_CHECK_HEADERS(stropts.h sys/time.h string.h unistd.h sys/systeminfo.h)
100 AC_CHECK_HEADERS(fcntl.h sys/fcntl.h, break)
101 AC_CHECK_HEADERS(sys/socket.h lan/socket.h, break)
102 AC_CHECK_HEADER(stddef.h, [], AC_DEFINE(X_WCHAR, 1))
103
104 AC_CHECK_FUNCS(_getpty grantpt setitimer usleep)
105 AC_CHECK_FUNCS(gettimeofday ftime, break)
106 AC_CHECK_FUNCS(random rand48, break)
107 AC_CHECK_FUNCS(gethostname sysinfo, break)
108 AC_CHECK_FUNC(setlocale, [],
109   AC_CHECK_LIB(i, setlocale, [], AC_DEFINE(X_LOCALE, 1)))
110
111 AC_CHECK_LIB(seq, getpseudotty)
112
113 dnl | add compiler warnings only if compiler understands them
114 AC_MSG_CHECKING(whether compiler understands -Wall -Wno-parentheses)
115 SAVE_CFLAGS="$CFLAGS"
116 CFLAGS="$CFLAGS -Wall -Wno-parentheses"
117 AC_TRY_COMPILE([],[],
118   AC_MSG_RESULT(yes),
119   AC_MSG_RESULT(no)
120   CFLAGS="$SAVE_CFLAGS")
121
122 dnl | check for cairo and librsvg
123
124 PKG_CHECK_MODULES([CAIRO], [ cairo >= 1.2.0 librsvg-2.0 >= 2.14.0 ])
125 AC_SUBST(CAIRO_CFLAGS)
126 AC_SUBST(CAIRO_LIBS)
127
128 dnl | check which front end to use
129 dnl | first check for gtk
130 dnl | then for Xaw3d
131 dnl | and then for Xaw
132 FRONTEND_CFLAGS=""
133 FRONTEND_LIBS=""
134
135 AC_ARG_WITH([gtk],
136             [AS_HELP_STRING([--with-gtk],[use GTK front-end (experimental)])],
137             [with_GTK=yes],
138             [with_GTK=no])
139
140 AC_ARG_WITH([Xaw3d],
141             [AS_HELP_STRING([--with-Xaw3d],[use Xaw3d front-end (not fully supported anymore)])],
142             [with_Xaw3d=yes],
143             [with_Xaw3d=no])
144
145 AC_ARG_WITH([Xaw],
146             [AS_HELP_STRING([--with-Xaw],[use Xaw front-end (default)])],
147             [with_Xaw=yes],
148             [with_Xaw=no])
149
150 dnl | check for libraries
151 if test x"$with_GTK" = x"yes" ; then
152   PKG_CHECK_MODULES([GTK], [ gtk+-2.0 >= 2.16.0 gmodule-2.0 ])
153   FRONTEND_CFLAGS=$GTK_CFLAGS
154   FRONTEND_LIBS=$GTK_LIBS
155 fi
156
157 if test x"$with_GTK" = x"no" ; then
158
159 dnl | general check for Xaw and Xaw3d
160   AC_PATH_XTRA
161   if test -n "$no_x" ; then
162     AC_MSG_ERROR([ "    $PACKAGE requires the X Window System header files and libraries!
163     They were not found on your system.  See FAQ topic C.2.
164     configure failed"])
165   fi
166
167   save_cflags="$CFLAGS"
168   save_cppflags="$CPPFLAGS"
169   CFLAGS="$CFLAGS $X_CFLAGS"
170   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
171   AC_CHECK_HEADER([X11/Intrinsic.h],[xt="yes"],[xt="no"])
172   CFLAGS="$save_cflags"
173   CPPFLAGS="$save_cppflags"
174
175   if test "$xt" = "no" ; then
176      AC_MSG_ERROR([Xt headers not found. Please install the X11 packages.])
177   fi
178
179 dnl | check availability of Xaw3d
180   FRONTEND_LIBS=
181   AS_IF([test x"$with_Xaw3d" != x"no"],
182             [AC_CHECK_LIB([Xaw3d],
183                     [XawTextReplace],
184                     [ FRONTEND_LIBS="-lXaw3d"
185                       AC_DEFINE([USE_XAW3D], [1], [Define if you want to use Xaw3d])],
186                     [AC_MSG_ERROR([--with-Xaw3d was given, but test for Xaw3d failed. Make sure that you have Xaw3d installed, else you might want to try the configure option --without-Xaw3d])],
187                                [-lXaw])])
188
189 dnl | no Xaw3d, check for Xaw; make it the default
190   if test x"$with_Xaw3d" = x"no" ; then
191      with_Xaw=yes
192      save_cflags="$CFLAGS"
193      save_cppflags="$CPPFLAGS"
194      CFLAGS="$CFLAGS $X_CFLAGS"
195      CPPFLAGS="$CPPFLAGS $X_CFLAGS"
196      AC_CHECK_HEADER([X11/Xaw/Dialog.h],[xaw_headers="yes"], [xaw_headers="no"])
197      CFLAGS="$save_cflags"
198      CPPFLAGS="$save_cppflags"
199
200      if test x"$xaw_headers" = x"no" ; then
201         AC_MSG_ERROR([Xaw headers not found. Please install the Xaw package and headers.])
202      fi
203
204      FRONTEND_LIBS="-lXaw"
205   fi
206
207 fi
208
209 dnl | make results available in Makefile.am
210 AM_CONDITIONAL([withGTK],   [test x"$with_GTK" = x"yes"])
211 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw3d" = x"yes"])
212 AM_CONDITIONAL([withXaw],   [test x"$with_Xaw" = x"yes"])
213
214
215 AC_SUBST(FRONTEND_CFLAGS)
216 AC_SUBST(FRONTEND_LIBS)
217
218 dnl | end Front-end check
219
220 AC_CANONICAL_HOST
221
222 dnl| The following info is mostly gathered from GNU Emacs 19.24.  Basically,
223 dnl| we are trying to find out whether this is a System-V derivative in
224 dnl| which pipes don't work with select() and if so, whether there is anything
225 dnl| strange about the way to open a pty.  Some of the work was done above
226 dnl| by looking for _getpty, grantpt, and getpseudotty.  A few other strange
227 dnl| properties of particular systems are also handled here.
228
229 dnl| 4/6/97 I'm not sure there really are any systems where pipes
230 dnl| don't work with select(), and ptys cause problems on many
231 dnl| systems, so I'm changing the default to disable ptys in all
232 dnl| cases.  I will change it back if I get bug reports that are fixed
233 dnl| by doing a "configure --enable-ptys"
234
235 USE_PTYS=0
236 case "$host" in
237   *-*-hpux* )
238     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
239         [sprintf (pty_name, "/dev/pty/tty%c%x", c, i);])
240     AC_DEFINE(PTY_NAME_SPRINTF,
241         [sprintf (pty_name, "/dev/ptym/pty%c%x", c, i);])
242 dnl| USE_PTYS=1
243     if test "$GCC" = yes; then
244       CONF_CFLAGS="-fwritable-strings"
245     else
246
247 dnl| Note: You might be able to build xboard even if your compiler does not
248 dnl| support ANSI C (-Aa).  xboard itself does not require ANSI C.  I don't
249 dnl| know whether the X header files on HP-UX require it.
250
251       CONF_CFLAGS="-Aa -D_HPUX_SOURCE"
252     fi
253
254 dnl| HP doesn't supply a full set of X header files and libraries.  People
255 dnl| often have some things installed in one place and some in another.
256 dnl| AC_PATH_XTRA will find only one place, so we try to add all the
257 dnl| likely ones that might be missing here.  It might be better to
258 dnl| change AC_PATH_XTRA to try to extract this information from imake,
259 dnl| since folks who install the missing bits often configure their
260 dnl| imake to find them, but I don't want to delve into autoconf and
261 dnl| hack on its internals.
262
263     if test -d /opt/hppd/include/X11; then
264       X_CFLAGS="$X_CFLAGS -I/opt/hppd/include"
265       X_LIBS="$X_LIBS -L/opt/hppd/lib"
266     elif test -d /usr/contrib/X11R5/include; then
267       X_CFLAGS="$X_CFLAGS -I/usr/contrib/X11R5/include"
268       X_LIBS="$X_LIBS -L/usr/contrib/X11R5/lib"
269     elif test -d /usr/contrib/mitX11R5/include; then
270       X_CFLAGS="$X_CFLAGS -I/usr/contrib/mitX11R5/include"
271       X_LIBS="$X_LIBS -L/usr/contrib/mitX11R5/lib"
272     elif test -d /MIT/X11R5/include; then
273       X_CFLAGS="$X_CFLAGS -I/MIT/X11R5/include"
274       X_LIBS="$X_LIBS -L/MIT/X11R5/lib"
275     elif test -d /usr/local/include/X11R5; then
276       X_CFLAGS="$X_CFLAGS -I/usr/local/include/X11R5"
277       X_LIBS="$X_LIBS -L/usr/local/lib/X11R5"
278     fi
279     if test -d /usr/include/X11R5; then
280       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R5"
281       X_LIBS="$X_LIBS -L/usr/lib/X11R5 -L/usr/lib/X11R4"
282     elif test -d /usr/include/X11R4; then
283       X_CFLAGS="$X_CFLAGS -I/usr/include/X11R4"
284       X_LIBS="$X_LIBS -L/usr/lib/X11R4"
285     fi
286   ;;
287
288   romp-ibm-aix* )
289     AC_DEFINE(IBMRTAIX, 1)
290 dnl| USE_PTYS=1
291   ;;
292
293   i386-ibm-aix )
294 dnl| USE_PTYS=1
295     if test "$GCC" = yes; then
296       CONF_CFLAGS="-fwritable-strings"
297     fi
298   ;;
299
300   *-*-aix3* | *-*-bosx* )
301     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
302     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
303     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [strcpy (pty_name, ttyname (fd));])
304 dnl| USE_PTYS=1
305   ;;
306
307   *-*-cxux* )
308     AC_DEFINE(FIRST_PTY_LETTER, 'A')
309     AC_DEFINE(LAST_PTY_LETTER, 'P')
310 dnl| USE_PTYS=1
311   ;;
312
313   *-*-uniplus* )
314     AC_DEFINE(UNIPLUS, 1)
315 dnl| USE_PTYS=1
316   ;;
317
318   *-*-rtu* )
319     AC_DEFINE(FIRST_PTY_LETTER, 'z')
320     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
321         [sprintf (pty_name, "/dev/ttyp%x", i);])
322     AC_DEFINE(PTY_NAME_SPRINTF,
323         [sprintf (pty_name, "/dev/pty%x", i);])
324     AC_DEFINE(RTU, 1)
325 dnl| USE_PTYS=1
326   ;;
327
328   *-*-iris* | *-*-irix3* )
329     AC_DEFINE(PTY_ITERATION, [for (c = 0; !c; c++)])
330     AC_DEFINE(PTY_NAME_SPRINTF, [strcpy (pty_name, "/dev/ptc");])
331     AC_DEFINE(PTY_TTY_NAME_SPRINTF,
332         [sprintf (pty_name, "/dev/ttyq%d", minor(stb.st_rdev));])
333 dnl| USE_PTYS=1
334   ;;
335
336   *-*-irix* )
337 dnl| USE_PTYS=1
338   ;;
339
340   *-*-sunos4* | *-*-solaris1* )
341
342 dnl| Work around a bug in the SunOS 4.x linker.  Not needed if you have patches
343 dnl|  100512-02 and 100573-03 from Sun.  The X FAQ says that the following is
344 dnl|  "overkill," but doesn't explain what should be done instead.
345
346     if test "$GCC" = yes; then
347       PRE_XMULIB="-static"
348       POST_XMULIB="-dynamic"
349     else
350       PRE_XMULIB="-Bstatic"
351       POST_XMULIB="-Bdynamic"
352     fi
353   ;;
354
355   *-*-sunos5* | *-*-solaris2* )
356 dnl| USE_PTYS=1
357
358 dnl| I'm not sure -lelf is needed, but it was in the old Imakefile.
359 dnl| The other libraries should all be found by Ac_PATH_XTRA or other
360 dnl| code above.
361
362     X_LIBS="$X_LIBS -lelf"
363   ;;
364
365   *-*-sco* )
366     AC_DEFINE(PTY_ITERATION, [for (i = 0; ; i++)])
367     AC_DEFINE(PTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ptyp%d", i);])
368     AC_DEFINE(PTY_TTY_NAME_SPRINTF, [sprintf (pty_name, "/dev/ttyp%d", i);])
369 dnl| USE_PTYS=1
370   ;;
371
372   *-*-dynix* | *-*-ptx* )
373 dnl| USE_PTYS=1
374   ;;
375
376   *-*-esix* )
377 dnl| USE_PTYS=1
378   ;;
379
380   *-*-usg5-4* | *-*-sysvr4* )
381 dnl| USE_PTYS=1
382   ;;
383
384   *-*-usg* | *-*-sysv* | *-*-aix* )
385 dnl| USE_PTYS=1
386   ;;
387
388   vax-*-ultrix )
389     if test "$GCC" = yes; then
390       CONF_CFLAGS="-fwritable-strings"
391     fi
392   ;;
393
394 dnl| add some libs for OS X
395   *-apple-* )
396   ;;
397 esac
398
399 AC_ARG_ENABLE(  [xpm],
400                 [AS_HELP_STRING([--enable-xpm],[libXpm will be used if found (default)])],
401                 [enable_xpm="$enableval"],
402                 [enable_xpm="yes"])
403
404 if test x"$enable_xpm" != "xno"; then
405   save_cflags="$CFLAGS"
406   save_cppflags="$CPPFLAGS"
407   CFLAGS="$CFLAGS $X_CFLAGS"
408   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
409   AC_CHECK_HEADERS(X11/xpm.h)
410   CFLAGS="$save_cflags"
411   CPPFLAGS="$save_cppflags"
412   if test "$ac_cv_header_X11_xpm_h" = "yes"; then
413     save_ldflags="$LDFLAGS"
414     LDFLAGS="$LDFLAGS $X_LIBS"
415     AC_CHECK_LIB(Xpm, XpmReadFileToPixmap,
416                  [X_PRE_LIBS="-lXpm $X_PRE_LIBS"; AC_DEFINE(HAVE_LIBXPM)], [],
417                  [$X_PRE_LIBS -lX11 $X_EXTRA_LIBS])
418     LDFLAGS="$save_ldflags"
419   fi
420 fi
421
422 AC_SUBST(PRE_XMULIB)
423 AC_SUBST(POST_XMULIB)
424 AC_SUBST(CONF_CFLAGS)
425 AC_SUBST(CONF_LDFLAGS)
426
427 AC_MSG_CHECKING(whether ptys or pipes should be used)
428 AC_ARG_ENABLE( [ptys],
429                [AS_HELP_STRING([--enable-ptys],[force use of pseudo-ttys with child processes])],
430 [if test "$enableval" = yes; then
431   USE_PTYS=1
432   enable_ptys="ptys"
433   AC_MSG_RESULT([ptys (user override)])
434 fi
435 if test "$enableval" = no; then
436   USE_PTYS=0
437   enable_ptys="pipes"
438   AC_MSG_RESULT([pipes (user override)])
439 fi],
440 [if test "$USE_PTYS" = 1; then
441   AC_MSG_RESULT(ptys)
442   enable_ptys="ptys"
443 else
444   AC_MSG_RESULT(pipes)
445   enable_ptys="pipes"
446 fi])
447 AC_DEFINE_UNQUOTED(USE_PTYS, $USE_PTYS)
448
449
450 dnl | define not to build zippy as a default, so that autoheader is happy
451 AC_ARG_ENABLE( [zippy],
452                [AS_HELP_STRING([--enable-zippy],[support interfacing a chess program to ICS (default)])],
453                [],
454                [enable_zippy="no"])
455
456 if test x"$enable_zippy" != xno; then
457   AC_DEFINE(ZIPPY, 1,[should zippy be enabled])
458 else
459   AC_DEFINE(ZIPPY, 0,[should zippy be enabled])
460 fi
461 AM_CONDITIONAL([ZIPPY], [test x$enable_zippy != xno])
462
463
464 AC_ARG_ENABLE(sigint,
465 [AS_HELP_STRING([--enable-sigint],[sending SIGINT (^C) wakes up GNU Chess (default)])],
466 [if test "$enableval" = yes; then
467   AC_DEFINE(ATTENTION, 1)
468 fi
469 enable_sigint=$enableval
470 ],
471 [enable_sigint="yes"
472 AC_DEFINE(ATTENTION, 1)])
473
474
475 if test x"$with_Xaw3d" = x"yes" -o  x"$with_Xaw" = x"yes" ; then
476 dnl | save all information for X in X_LIBS, also add the libraries themself
477 dnl | since AC_PATH_XTRA only adds the paths
478 X_LIBS="$X_PRE_LIBS $X_LIBS $X_EXTRA_LIBS -lXmu -lX11 -lXt "
479 AC_SUBST(X_CFLAGS)
480 AC_SUBST(X_LIBS)
481 fi
482
483 dnl | should we install desktop icons and mime associations?
484 AC_ARG_ENABLE(  [update-mimedb],
485                 [AS_HELP_STRING([--disable-update-mimedb],[disable the update-mime-database after install [default=no]])],
486                 [enable_mimedb="no"],
487                 [enable_mimedb="yes"])
488
489 AM_CONDITIONAL(ENABLE_UPDATE_MIMEDB, test x"$enable_mimedb" = "xyes")
490
491 if test x"$enable_mimedb" = "xyes"; then
492    AC_PATH_PROG([XDG_MIME],[xdg-mime])
493    AC_SUBST(XDG_MIME)
494    AC_PATH_PROG([XDG_DESKTOP_MENU],[xdg-desktop-menu])
495    AC_SUBST(XDG_DESKTOP_MENU)
496    AC_PATH_PROG([XDG_ICON_RESOURCE],[xdg-icon-resource])
497    AC_SUBST(XDG_ICON_RESOURCE)
498 fi
499
500 dnl |  output Makefile
501 AC_CONFIG_FILES([Makefile cmail po/Makefile.in])
502 AC_CONFIG_COMMANDS([test-stamp-h],[test -z "$CONFIG_HEADERS" || date > stamp-h])
503 AC_CONFIG_COMMANDS([chmod-cmail],[chmod 755 cmail])
504 AC_OUTPUT
505
506 dnl
507 dnl Output a summary
508 dnl
509 echo ""
510 echo " Configurations summary:"
511 echo ""
512 echo "        prefix:          $prefix       "
513 echo "        datarootdir:     $datarootdir  "
514 echo "        datadir:         $datadir   (icons will go in \$datadir/icons/hicolor/...)"
515 echo "                                    (bitmaps will go in \$datadir/games/xboard/...)"
516 echo "        infodir:         $infodir   (info files will go here)"
517 echo "        sysconfdir:      $sysconfdir   (xboard.conf will go here)"
518 echo ""
519 echo "        update mimedb:   $enable_mimedb"
520 echo ""
521 echo "        NLS support:     $USE_NLS"
522 echo ""
523 echo "        GTK:             $with_GTK"
524 echo "        Xaw3d:           $with_Xaw3d"
525 echo "        Xaw:             $with_Xaw"
526 echo ""
527 echo "        xpm:             $enable_xpm"
528 echo "        ptys:            $enable_ptys"
529 echo "        zippy:           $enable_zippy"
530 echo "        sigint:          $enable_sigint"